Excel: logboek bijhouden van bestede tijd aan een Excel bestand

Tijdens een VBA cursus kwam de vraag om in een logboek bij te houden wie er in welke werkmap hoe lang gewerkt had op welke datum. Een leuke vraag met naar mijn smaak een leuk resultaat.

De oplossing in VBA ziet er uiteindelijk zo uit. Achter ThisWorkBook coderen we de gebeurtenissen BeforeClose en Open. De code ziet er zo uit:

Option Explicit

Public datOpen As Date

Public Sub Workbook_BeforeClose(Cancel As Boolean)
    Dim datSluit As Date
    Dim strGebruiker As String
    Dim strWbNaam As String
    
    strGebruiker = Environ("Username")
    datSluit = Now()
    strWbNaam = ThisWorkbook.Name
    Call logBoek(strWbNaam, strGebruiker, datOpen, datSluit)
End Sub

Public Sub Workbook_Open()
    datOpen = Now()
End Sub

De aangeroepen procedure logBoek zetten we in een VBA module.

Public Sub logBoek(strWbNaam As String, strGebruiker As String, datOpen As Date, datSluit As Date)
    Dim intRows As Integer
    Dim datDuur As Long
    Dim strPad As String
    
    'pad instellen waar het logboek staat
    strPad = "D:\data\walmar\cursussen\cursusmateriaal\Excel\Oefeningen\"
    
    'gewerkte tijd in seconden uitrekenen: verschil tijd van openen en sluiten
    datDuur = DateDiff("s", datOpen, datSluit)
    
    'testen of het logboek open of gesloten is
    If Not IsBookOpen("Logboek.xlsm") Then
        Workbooks.Open (strPad & "Logboek.xlsm")
    End If

    'communicatie met het scherm uitzetten
    Application.ScreenUpdating = False
    Workbooks("Logboek.xlsm").Sheets("Blad1").Activate
    
    'uitrekenen op welke rij in Logboek.xlsm de waarden toegevoegd moeten worden
    intRows = Workbooks("Logboek.xlsm").Sheets("blad1").UsedRange.Rows.Count + 1
    With Workbooks("Logboek.xlsm").Sheets("Blad1").Cells(intRows, 1)
        .Offset(0, 0).Value = strWbNaam
        .Offset(0, 1).Value = strGebruiker
        .Offset(0, 2).Value = datOpen
        .Offset(0, 3).Value = datSluit
        .Offset(0, 4).Value = datDuur
    End With
    
    'werkboek bewaren en sluiten
    ActiveWorkbook.Save
    ActiveWorkbook.Close
    
    'communicatie met het scherm uitzetten
    Application.ScreenUpdating = True
End Sub

Function IsBookOpen(ByRef BookName As String) As Boolean
    On Error Resume Next
    IsBookOpen = Not (Application.Workbooks(BookName) Is Nothing)
End Function

In logboek.xlsm zien we dan verschijnen:

bestand	gebruiker	geopend	gesloten	duur in sec
Wijzigingslog.xlsm	hessel	18-10-2014 11:21	18-10-2014 11:22	86
Wijzigingslog.xlsm	hessel	18-10-2014 11:22	18-10-2014 11:23	46

Bijbehorende bestanden zitten in Wijzigingslog.zip en dat is te downloaden via:

https://drive.google.com/folderview?id=0B7HgkOwFZtdZVmhRQUZFM28yc1U&usp=sharing

Verdere tips: je kunt het bestand exceltips.pdf (laatst gewijzigd (12-9-2014) hier downloaden:

https://drive.google.com/folderview?id=0B7HgkOwFZtdZVmhRQUZFM28yc1U&usp=sharing