donderdag 16 juni 2016

VBA: script om internet explorer pagina's geautomatiseerd om te zetten in PDF's

De aanleiding voor dit script is de behoefte om geautomatiseerd een aantal rapporten van Reporting Services om te zetten naar PDF formaat.

Het onderstaande VBA script is algemeen te gebruiken om een willekeurige internet pagina om te zetten naar PDF. Het kan aangeroepen worden vanuit elk Office pakket. Zelf heb ik het gemaakt in Access.

Voor het omzetten van de internet pagina naar PDF heb ik gebruik gemaakt van de PDFCreator. Dit kan gratis worden gedownload: http://www.pdfforge.org/

De PDFCreator kan als printer worden aangeroepen met VBA. Binnen dit programma kunnen we een aantal zaken instellen zoals de map waarin we de PDF's willen opslaan.


Het VBA script:

'functie nodig om de standaard printer aan te passen
Private Declare Function SetDefaultPrinter Lib "winspool.drv" Alias "SetDefaultPrinterA" (ByVal pszPrinter As String) As Long

Sub printURL()
    Dim objExplorer As Object
    Dim lngQuery As Long 'geef waarde QueryStatusWB
    Dim intTeller As Integer
    Dim sglTime As Single
    Dim prtDefault As Printer
    Dim strURL As String

    'URL instellen
    strURL = "http://www.google.nl"

    'Internet Explorer starten, zichtbaar maken en van een pagina voorzien
    Set objExplorer = CreateObject("InternetExplorer.Application")
    objExplorer.Visible = True
    objExplorer.Navigate strURL

    'startprinter vastleggen
    Set prtDefault = Application.Printer 'huidige printer vastleggen
    'MsgBox prtDefault.DeviceName

    'printer instellen door functie aan te roepen; download PDFcreator
    SetDefaultPrinter ("PDFCreator")

Herhaal:
        'Wacht 5 seconden zodat IE de pagina kan laden
        sglTime = Timer
        Do While sglTime > Timer - 5
            DoEvents
            'The DoEvents function surrenders execution of the macro so that the operating system can process other events.
            'The DoEvents function passes control from the application to the operating system.
        Loop
        lngQuery = objExplorer.QueryStatusWB(6)  'command status van de printer

        If lngQuery And 2 Then
            objExplorer.ExecWB 6, 2, "", ""   'Ok om af te drukken? Voer het Printcommando uit (6) zonder print venster te tonen (2)
            '1 toont print venster wel
            'wacht 5 seconden zodat IE kan afdrukken
            sglTime = Timer
            Do While sglTime > Timer - 5
                DoEvents
            Loop
        Else
            GoTo Herhaal
        End If

    'internet explorer sluiten en object verwijderen
    objExplorer.Quit
    Set objExplorer = Nothing

    'oorspronkelijke printer terugzetten
    SetDefaultPrinter (prtDefault.DeviceName)
End Sub
Een reactie posten